COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN "SYNDMP"
C00004 ENDMK
C⊗;
BEGIN "SYNDMP"
comment display any residual XGPSYN queued files;
INTEGER CH,COUNT,BRCHAR,EOF,FLAG,I;
REQUIRE "VIXHDR.SAI[VIS,HPM]" SOURCE_FILE;

CH←GETCHAN;

OPEN(CH,"DSK",'10,19,0,COUNT,BRCHAR,EOF);
LOOKUP(CH,"TMPHPM.UFD[1,1]",FLAG);

WHILE ¬EOF DO
DO BEGIN "FILES"
   INTEGER ARRAY RET[0:'17]; INTEGER FN,EXT; STRING SFN,SEXT;
   ARRYIN(CH,RET[0],'20); FN←RET[0]; IF FN=0 THEN DONE "FILES";
   EXT←RET[1];
   SFN←CVXSTR(FN);  WHILE SFN[∞ TO ∞]=" " DO SFN←SFN[1 TO ∞-1];
   SEXT←CVXSTR(EXT LAND '777777000000);
		   WHILE SEXT[∞ TO ∞]=" " DO SEXT←SEXT[1 TO ∞-1];
   IF LENGTH(SFN)<5 ∨ ¬EQU(SEXT,"TMP") THEN DONE "FILES";
   FOR I←1 STEP 1 UNTIL LENGTH(SFN) DO
      IF SFN[I TO I]<"0" ∨ SFN[I TO I]>"9" THEN DONE "FILES";
   I←PFLDIM("DSK:"&SFN&".TMP[TMP,HPM]");
   IF I>50000 THEN
      BEGIN
      INTEGER ARRAY PIC[0:I];
      PRINT("DSK:"&SFN&".TMP[TMP,HPM]",'15&'12);
      GETPFL("DSK:"&SFN&".TMP[TMP,HPM]",PIC[0]);
      IF VIDXGP(PIC[0],0,-36,2200,1) THEN
	 BEGIN INTEGER COUNT,BRCHAR,EOF,CH,FLAG;  comment delete the XGP'd file;
	 CH←GETCHAN;
	 OPEN(CH,"DSK",'10,0,1,COUNT,BRCHAR,EOF);
	 ENTER(CH,SFN&".TMP[TMP,HPM]",FLAG);
	 RENAME(CH,"",0,FLAG);
	 RELEASE(CH);
	 END;
      END;
   END "FILES" UNTIL TRUE;
END;